####################################################
##
##  Files for the ddt-util-gui library
##
####################################################

# List all the source files from this directory.
# This list will be used in the parent directory, so
# prefix each file with CMAKE_CURRENT_SOURCE_DIR.

set (terminal_SOURCES
        ${CMAKE_CURRENT_SOURCE_DIR}/terminalwindow.cpp
        ${CMAKE_CURRENT_SOURCE_DIR}/terminalutil.cpp
        ${CMAKE_CURRENT_SOURCE_DIR}/terminalwidget.cpp
        ${CMAKE_CURRENT_SOURCE_DIR}/terminal.cpp
        ${CMAKE_CURRENT_SOURCE_DIR}/terminalprocess.cpp
        # NB: No PARENT_SCOPE here - we will append to the list first (below)
        )

if (WIN32)
    list (APPEND terminal_SOURCES
            ${CMAKE_CURRENT_SOURCE_DIR}/terminal_win.cpp
            )
else (WIN32)
    list (APPEND terminal_SOURCES
            ${CMAKE_CURRENT_SOURCE_DIR}/terminal_unix.cpp
            ${CMAKE_CURRENT_SOURCE_DIR}/terminalprocess_unix.cpp
            )
endif (WIN32)

# Propagate modified list to the parent scope.
set (terminal_SOURCES ${terminal_SOURCES} PARENT_SCOPE)

####################################################
##
##  Targets
##
####################################################


# Compile and link executable (just used for testing)
add_executable (term
        term_main.cpp
        )

target_link_libraries (term
        ddt-util-gui
        )

# This is a test binary :- output it in the CMAKE_CURRENT_BINARY_DIR rather than the
# CMAKE_RUNTIME_OUTPUT_DIRECTORY.
set_target_properties (term PROPERTIES
        RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
        )
